;hsqcetfpgpsi2
;with SIERRA filter
;avance-version (11/02/24)
;LWA 6/18/18
;HSQC
;2D H-1/X correlation via double inept transfer
;   using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection
;with decoupling during acquisition
;using flip-back pulse
;with gradients in back-inept
;
;A.G. Palmer III, J. Cavanagh, P.E. Wright & M. Rance, J. Magn.
;   Reson. 93, 151-170 (1991)
;L.E. Kay, P. Keifer & T. Saarinen, J. Am. Chem. Soc. 114,
;   10663-5 (1992)
;J. Schleucher, M. Schwendinger, M. Sattler, P. Schmidt, O. Schedletzky,
;   S.J. Glaser, O.W. Sorensen & C. Griesinger, J. Biomol. NMR 4,
;   301-306 (1994)
;S. Grzesiek & A. Bax, J. Am. Chem. Soc. 115, 12593-12594 (1993)
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


prosol relations=<triple>


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

; define target frequencies
; use cnst10 (1H) and cnst20 (13C)
; for manual optimization

define list<frequency> fH = {cnst10} 
define list<frequency> fC = {cnst20}

"p2=p1*2"
"p4=p3*2"

"d4=1s/(4*cnst2)"
"d24=1s/(8*cnst2)"

; define Tcp
; comment out for manual optimization
"d10=1s/(cnst4)"


"d11=30m"

"d0=3u"

"in0=inf1/2"

; auto power calculation, 
; scaling factor may need to be adjusted for individual spectrometers
; comment out for manual optimization
; set cnst1=1 for pwr on and cnst1=0 for pwr off

;"plw10=cnst1*(plw1*100.531*p1*1E-6)/(1.732051*cnst4)"
;"plw20=cnst1*(plw2*100.531*p3*1E-6)/(1.732051*cnst4)"


# ifdef SELECTIVE
"DELTA=p16+d16+d0*2+p2+d5"
# else
"DELTA=p16+d16+d0*2+p2"
# endif /*SELECTIVE*/

"DELTA1=p16+d16-p1*0.78+de+8u"
"DELTA2=d24-p19-d16"
"DELTA3=d4-p16-d16"

"cnst0=0"

"acqt0=0"

baseopt_echo

1 ze
  d11 pl12:f2 pl1:f1
2 d1 do:f2
3 3u fH.res fC.res 
4 ; Begin SIERRA Filter
	3u pl10:f1 pl20:f2   					; set CP power levels
	3u fq=fH:f1 fq=fC:f2 					; set CP frequencies 
d10 cw:f1 ph10:r cw:f2 ph20:r UNBLKGRAD ; begin CP
	3u do:f1 do:f2								;end CP

	3u pl1:f1 fq=cnst0:f1
(p2 ph2):f1
	3u pl10:f1 fq=cnst10:f1

d10 cw:f1 ph10:r  							;begin CP
	3u do:f1 do:f2								;end CP

	3u fH.inc
	3u fC.inc

	3u pl1:f1  pl2:f2
	3u fq=cnst0:f1 fq=cnst0:f2
(p1*2 ph2):f1

lo to 4 times l3
	3u
p18:gp6
	d16

; Begin HSQC

(p1 ph1)
 
  d4 
 
(center (p2 ph2) (p4 ph6):f2 )

  d4 

(p1 ph2) 

  4u pl0:f1
(p11:sp1 ph8:r):f1
  4u
  
p17:gp1
  d16 pl1:f1 
  
#ifdef SELECTIVE
(p23:sp23 ph3):f2 
#else
(p3 ph3):f2
# endif /*SELECTIVE */

  d0 
  
(p2 ph7):f1

  d0

p16:gp2*EA
  d16 

#ifdef SELECTIVE
(p24:sp24 ph4):f2 
#else
(p4 ph4):f2
# endif /*SELECTIVE */
  
	DELTA pl2:f2
  
(center (p1 ph1) (p3 ph4):f2 )

p19:gp4
  d16

  DELTA2

(center (p2 ph1) (p4 ph1):f2 )

  DELTA2
 
p19:gp4
  d16

(center (p1 ph2) (p3 ph5):f2 )

p16:gp5
  d16

  DELTA3

(center (p2 ph1) (p4 ph1):f2 )

  DELTA3

p16:gp5
  d16

(p1 ph1)

  DELTA1

(p2 ph1)

  4u
p16:gp3
  d16 pl12:f2
 
  4u BLKGRAD
 
  go=2 ph31 cpd2:f2
  d1 do:f2 mc #0 to 2 
     F1EA(calgrad(EA) & calph(ph5, +180), caldel(d0, +in0) & calph(ph3, +180) & calph(ph6, +180) & calph(ph31, +180))
exit
   

ph1=0 
ph2=1
ph3=0 2
ph4=0 0 2 2
ph5=1 1 3 3
ph6=0
ph7=0 0 2 2
ph8=2
ph10=0
ph20=0
ph31=2 0 0 2
  

;pl0 : 0W Dummy power
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;pl10: f1 channel - CP power
;pl20: f2 channel - CP power
;sp1 : f1 channel - shaped pulse  90 degree
;spnam1: Squa.100.1000
;spnam23: f2 channel - shaped pulse 90 degree
;spnam24: f2 channel - shapled pulse 180 degree
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;p11: f1 channel -  90 degree shaped pulse
;p16: homospoil/gradient pulse [1 msec]
;p17: Post-INEPT Z-filter 
;p18: SIERRA Z-filter 
;p19: gradient pulse 2         [600 usec]
;p23: f2 channel shaped 90 degree pulse
;p24: f2 channel shaped 180 degree pulse
;d0 : incremented delay (2D)   [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4: 1/(4J(YH))
;d10: Tcp 1/JCH
;d11: delay for disk I/O  [30 msec]
;d16: delay for homospoil/gradient recovery
;d24: 1/(8J) for CH3
;     1/(4J) for XH
;d5: seletive pulse compensation delay
;cnst0: reset carriers to o1/o2 frequencies
;cnst1: CP power flag
;				1 = pwr on 0 = pwr off
;cnst2: = JCH; for INEPT Delay
;cnst4 = JCH; for CP parameters
;cnst10: 1H CP offset (Hz)
;cnst20: 13C CP offset (Hz)
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;NS: 1 * n
;DS: >= 16
;td1: number of experiments
;l3: SIERRA loop counter
;FnMODE: echo-antiecho
;cpd2: decoupling according to sequence defined by cpdprg2

;pcpd2: f2 channel - 90 degree pulse for decoupling sequence


;use gradient ratio:  gp 1 : gp 2 : gp 3 : gp 4 : gp 5 : gp 6
;                       50 :   80 : 20.1 :    5 :   -2 :   95     for C-13
;                       50 :   80 :  8.1 :    5 :   -2 :   95     for N-15

;for z-only gradients:
;gpz1: 50%
;gpz2: 80%
;gpz3: 8.1% for N-15, 20.1% for C-13
;gpz4: 5%
;gpz5: -2%
;gpz6: 95%

;use gradient files:   
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.50
;gpnam5: SMSQ10.100
;gpnam6: SMSQ10.100

						;preprocessor-flags start
;SELECTIVE: for 13C seletive pulsing
;						option -DSELECTIVE 
						;preprocessor-flags-end

;$Id: hsqcetfpgpsi2,v 1.2.2.2 2011/02/24 17:27:48 ber Exp $